Connect your devices. Watch every reading live.

// Arduino IDE / PlatformIO. Libraries: PubSubClient, ArduinoJson
#include <WiFi.h>
#include <WiFiClientSecure.h>
#include <PubSubClient.h>
#include <ArduinoJson.h>

const char* DEVICE_ID = "dev_xxxxxxxxxxxx";      // from the dashboard
const char* PASSWORD  = "your-device-password";
const char* BROKER    = "iot.aiota.tech";

WiFiClientSecure net;
PubSubClient mqtt(net);
String base = String("devices/") + DEVICE_ID;

void onCommand(char* topic, byte* payload, unsigned int len) {
  JsonDocument doc;
  if (deserializeJson(doc, payload, len)) return;
  const char* cmd = doc["command"] | "";
  if (strcmp(cmd, "relay_on") == 0)  digitalWrite(2, HIGH);
  if (strcmp(cmd, "relay_off") == 0) digitalWrite(2, LOW);
}

void connectMqtt() {
  while (!mqtt.connected()) {
    String status = base + "/status";
    // Last Will: the broker publishes "offline" if the device drops
    if (mqtt.connect(DEVICE_ID, DEVICE_ID, PASSWORD, status.c_str(), 1, true, "offline")) {
      mqtt.publish(status.c_str(), "online", true);
      mqtt.subscribe((base + "/cmd").c_str(), 1);
    } else delay(5000);
  }
}

void setup() {
  pinMode(2, OUTPUT);
  WiFi.begin("wifi-name", "wifi-password");
  while (WiFi.status() != WL_CONNECTED) delay(500);
  net.setInsecure();            // for production use net.setCACert(rootCA)
  mqtt.setServer(BROKER, 8883);
  mqtt.setCallback(onCommand);
}

void loop() {
  if (!mqtt.connected()) connectMqtt();
  mqtt.loop();
  static unsigned long last = 0;
  if (millis() - last > 5000) {
    last = millis();
    JsonDocument doc;
    doc["temperature"] = temperatureRead();
    doc["rssi"] = WiFi.RSSI();
    char buf[200];
    size_t n = serializeJson(doc, buf);
    mqtt.publish((base + "/telemetry").c_str(), (uint8_t*)buf, n, false);
  }
}